Aminet 33/Aminet 33 - October 1999.iso/Aminet/util/time/backclock.lha/backclock/Install

Text File | 1999-08-16 | 5.2 KB | 210 lines

;/* install script version 1.4
; * $VER: BCInstall 1.4 (16-06-99)
; */

; set some constant

(set #inst_text "BackClock Installation on Hard Disk")
(set #prog "backclock")
(set #rtlib  "rtracker.library")
(set #ledlib "led.image")
(set @appname "BackClock")
(set #gosrc      1)
(set #gobootup   1)
(set #defpathprefs "sys:prefs/")
(set #libs_src "libs")
(set #libs_dst "libs:")
(set #clas_dst "SYS:Classes/images")
(set #prefsprompt "Do you want to install default preferences\nThis will erase your last settings !")
(set #prefshelp "This will overwrite the file\nbackclock.prefs in env: & envarc:")
(set #destdir_prompt "Where do you want to install BackClock\nA drawer will be created.")
(set #destdirprefs   "Where do you want to install BackClock preferences.")

; asks where to put the prog
(set #destdir (askdir
    (prompt #destdir_prompt)
    (help @askdir-help)
    (default "Work:")
  )
)


(set @default-dest (tackon #destdir "BackClock"))
(if (not (exists (@default-dest)))
  (makedir @default-dest (infos))
)


; update rtracker.library if needed
(copylib
  (prompt  "Updating rtracker.library")
  (source  (tackon #libs_src #rtlib))
  (dest    #libs_dst)
  (help    @copylib-help)
  (confirm expert)
)
; update or copy led.image
(copylib
  (prompt "Update or copy led.image")
  (source (tackon #libs_src #ledlib))
  (dest   #clas_dst)
  (help    @copylib-help)
  (confirm expert)
)

; asks if the user wants to start backclock at startup
(if (>= @user-level 1)
  (set #gobootup
    (askbool
      (prompt "Do you want to run BackClock each startup ?")
      (help   "If you answer yes, then BackClock will be copied to SYS:WBStartup.")
    )
  )
)

(set #sourcepath @default-dest)

; asks the path for the prefs prog (BCPrefs & style)
(if (>= @user-level 1)
  (set #defpathprefs (askdir
    (prompt #destdirprefs)
    (help   "Please choose where to place the preferences utility.")
    (default #defpathprefs)
    )
  )
)
(if (>= @user-level 1)
  (if (askbool
        (prompt "Do you want to install sources ?")
        (help   "This will install the sources of the program in the directory sources./")
      )
      (
        ;install sources
        (set #gosrc 1)
        (if (= 2 @user-level)
          (
            (set #sourcepath (askdir
                (prompt "Where do you want to install sources codes ?\nA drawer called sources will be created there.")
                (help   "You have to choose where the sources be placed.")
                (default @default-dest)
              )
            )
          )
        )
      )
      ; don't install sources
      (set #gosrc 0)
  )
)
; asks the user if he wants to use default prefs
(run "c/defconf"
  (prompt #prefsprompt)
  (help   #prefshelp)
  (confirm)
)

; here the script asks for the guide to install
; english or german
(set #catalog
  (askchoice
    (prompt "Select your desired guide file")
    (help   "If you know english then choose english\nIf you know german then choose german")
    (choices "English" "German" "Français")
    (default 0)
  )
)
; copies the sources
(if (= 1 #gosrc)
  ((if (not (exists (tackon #sourcepath "sources")))
               (makedir (tackon #sourcepath "sources"))
            )
  )
)

; not preset directory ?
(if (not (exists "sys:prefs/presets"))
  (makedir "sys:prefs/presets")
)

; copy the presets
(copyfiles
  (prompt "Copying presets")
  (help   "This whill copy presets to sys:prefs/presets\nYou can change presets by using it in the preferences")
  (source "presets")
  (dest   "sys:prefs/presets")
  (all)
)

; copy the main files
(copyfiles
  (prompt "Copying Main file")
  (help   "Copy the executable and the icon of the main file in the path you choosed")
  (source "bin/")
  (dest   @default-dest)
  (all)
)
(copyfiles
  (prompt "Copying preferences program")
  (help   "Copy the preferences executable and the icon file in the path you choosed")
  (source "prefs/")
  (dest   #defpathprefs)
  (all)
)
; copies the guide
(if (= #catalog 0)
  (copyfiles
    (prompt "Copying documentation")
    (help   "Copy the documentation in the path you choosed")
    (source "docs/backclockE.guide")
    (newname "backclock.guide")
    (dest   @default-dest)
  )
)
(if (= #catalog 1)
  (copyfiles
    (prompt "Copying documentation")
    (help   "Copy the documentation in the path you choosed")
    (source "docs/backclockD.guide")
    (newname "backclock.guide")
    (dest   @default-dest)
  )
)
(if (= #catalog 2)
  (copyfiles
    (prompt "Copying documentation")
    (help   "Copy the documentation in the path you choosed")
    (source "docs/backclockF.guide")
    (newname "backclock.guide")
    (dest   @default-dest)
  )
)
; copies the guide icon
(copyfiles
  (prompt "Copying icon documentation")
  (help   "This copies the icon file for the documentation at the desired place")
  (source "docs/BackClock.Guide.info")
  (dest   @default-dest)
)

; place backclock in the wbstartup
(if (= 1 #gobootup)
  (copyfiles
    (prompt "Copying to WBStartup")
    (help   "Copy the executable file to wbstartup\nThis will run BackClock each reboot.")
    (source "bin/backclock")
    (dest   "SYS:WBstartup/")
    (infos)
  )
)

(if (= 1 #gosrc)
  (copyfiles
    (prompt "Copying sources")
    (help   "Copy the sources in C in the the path you choosed")
    (source "sources/")
    (dest   (tackon #sourcepath "sources"))
    (all)
  )
)